;PKPM桩筏筏板有限元配筋过滤[mini_zfpj].lsp
(defun C:mini_ZFPJ ( / fGZPJ ss edata sText lstText bDel)

	(mai_start nil)
	(mai_last_com "mini_ZFPJ")
	(setq fGZPJ (getreal "\n过滤配筋量(结束：仅删除构造配筋):<0>"))
	(or fGZPJ (setq fGZPJ 0))
	(setq
		ss (mai_select_first
				'((0 . "text") (1 . "*AU*,*AD*"))
				"选择PKPM配筋文字:<退出>"
				"没有找到单行文字."
			)
	)
	(foreach ename (mai_ssget_2_list ss)
		(setq
			edata (entget ename)
			sText (mai_dxf 1 edata)
			lstText nil
		)
		(cond
			(	(wcmatch sText "*AU*")	;板面钢筋
				(setq lstText (mai_str2lst2 sText "xAUy"))
			)
			
			(	(wcmatch sText "*AD*")	;板底钢筋
				(setq lstText (mai_str2lst2 sText "xADy"))
			)
			
			(	T
				(setq lstText nil)	;构造配筋
			)
		)
		(setq bDel T)
		(and
			(car lstText)
			(> (atof (car lstText)) fGZPJ)
			(setq bDel nil)
		)		;X向配筋非构造
		(and
			(cadr lstText)
			(> (atof (cadr lstText)) fGZPJ)
			(setq bDel nil)
		)	;Y向配筋非构造
		(if bDel (entdel ename))
	)
	(mai_End)
)
